 101 400       job  1401 Fortran compiler tape generator                   50994
 102           ctl  645 11
 1021*
 1022* Load overlays.
 1023* Write them from their beginning addresses onto tape.
 1024* Add branch to start of program in 001-014 of the first block.
 1025* Load relocatable functions as card images.
 1026*
 103           xinitx1,x2,x3
 104 xbegin    equ  838
 105           org  6000
 106 begin     r                  skip               
 107           ss   1               clear            
 108           r                      core           
 109           ss   1                   cards        
 110           r                  read bootstrap  
 111           ss   1               card
 112           rwd  1
 1134          sbr  71,nutap&1    trap end of bootstrap
 1144          sw   1             ready to run bootstrap
 1151          b    1             run bootstrap                       v4
 1152*                                                                v4
 1153* End of function block                                          v4
 1154*                                                                v4
 1155ndfun     sw   1                                                 v4
 1156          cw   80            no wm under GM in 80                v4
 1161*
 1162* Read one overlay and write it on tape
 1163*
 117 nutap     r
 118           ss   1
 119           bce  nutap,54,     overlay loader card                 v4
 121           c    4,@]]]]@                      all 11-5-8
 122           be   funct         start of relocatable library
 123           bwz  *&5,44,2      load is in 0k, 4k, 8k or 12k
 124           b    mov
 125           c    46,@111@      q. segment name or index card
 126           bh   nutap           yes -- assumes load addr lt 4k
 127 mov       mcw  46,lod&6      move load instr here
 128 lod       lca  0,0           load instr from card
 129           sbr  x1            save load address
 130 runit     sbr  71,retrn      trap the end of the load            v4
 131           b    40            run the load code on the card       v4
 133 retrn     ss   1               and come back here
 1344          bce  runit,40,l    run the card if it is a load card
 1374ckfst     nop                to turn off the next branch         v4
 138           b    first         branch only once
 139 put       wtw  1,1&x1        write the block
 140           ber  tperr
 141           blc  end
 142           cs   20            clear the boot block if there is one
 143           sw   1
 1444          sbr  x2,2999       get ready to clear 2999             v4
 1449          sw   300             down to 300                       v4
 145 cleer     cs   0&x2          clear one century
 146           sbr  x2            keep track
 1474          bw   cleer,300     branch if not done                  v4
 149           b    nutap         do another block
 1491*
 1492* Tape error handler
 1493*
 1501tperr     sbr  x3                                                v4
 1502          bsp  1                                                 v4
 151           skp  1
 152           s    &1,count
 153           bwz  erxt,count,b
 154           messg@bad tape one - replace and restart@,65,1,1
 155           h    1111,1111
 156           mcw  &10,count
 157 erxt      b    16000-13&x3
 1571*
 1572* All done
 1573*
 158 end       wtm  1
 159           rwd  1
 160           messg@1401 Fortran compiler generated on tu 1@,70,1,1
 161 eoj       h    2222,2222
 162           b    eoj
 1621*
 1622* Write relocatable library as card images
 1623*
 163 funct     cw   1
 165 lgm       lca  @}@,80          gm
 1654          bce  ovlay,54,     overlay loader card
 166           wtw  1,1
 167           ber  tperr
 168           c    4,@;;;;@      all 11-6-8
 169           be   ndfun         finished with functions
 170 ovlay     r
 171           ssb  lgm,1
 1751*
 1752* Load link to start of code into 001-014 in first block
 1753*
 1764first     cw   ckfst&1       turn off branch to here             v4
 177           lca  fixed,14
 178           lca
 179           lca
 180           lca
 1804          sbr  x1,0          write the first block from 001      v4
 181           b    put
 1841*
 1842* Code to move to 001-014 of first block, to branch to start
 1843*
 1854          ber  10                                                v4
 1865          b    xbegin                                            v4
 1884          h    10                                                v4
 189 fixed     dcw  0
 190 count     dcw  10            count of write errors
 193           end  begin
