 101 003       job  1401 Fortran compiler tape generator                   50993
 102           ctl  645 11
 103           xinitx1,x2,x3
 104 xbegin    equ  838
 105           org  6000
 106 begin     r                Skip
 107           ss   1
 108           r                  Boot
 109           ss   1
 110           r                    Cards
 111           ss   1
 112           rwd  1
 113           sw   1,40        Setup
 114           sw   47,54         Loader
 115           sw   61,68           Word
 116           sw   72                Marks
 117 nutap     r
 118           ss   1
 119           c    4,@,015@    Q. Overlay restart card
 120           bu   keepit      A. No, keep it
               r                Skip the next one too
               ssb  nutap,1
 121 keepit    c    4,@]]]]@                      all 11-5-8
 122           be   funct
 123           bwz  *&5,44,2
 124           b    mov
 125           c    46,@111@    Skip cards that
 126           bh   nutap         load below 110
 127 mov       mcw  46,lod&6    Get the load instruction from the card
 128 lod       lca  0,0         First card of overlay
 129           sbr  x1          Save write address
 130           sbr  71,retrn    Come back to retrn
 131           b    47            after executing the load
 132 retrn     ss   1           Loader reads next card
 134           bce  first,40,/  End of deck
               sbr  71,first
               bce  40,68,b     Overlay entry card
 136           sbr  71,retrn    Not an overlay entry card
 137           b    40          Execute the load
     *
     * First program overlay record.  Insert link to program start
     *
     first     bin  put,}       D is GM, gets WM to turn on branch
               sw   first&4     Turn on branch
 177           lca  fixed,14    Insert
 178           lca                link to
 179           lca                  program
 180           lca                    start
               sbr  x1,0
 181           b    put
     *
     * Tape error
     *
 150 tperr     bsp  1
 151           skp  1
 152           a    *-6,count
 153           bce  erxt,count-1,0
 154           messg@bad tape one - replace and restart@,65,1,1
               nop  1111
 155           h
 156           za   count
 157 erxt      bin  lgm,}       D is GM, gets WM to turn on branch
     *
     * Write program overlay record
     *
 139 put       wtw  1,1&x1
 140           ber  tperr
 141           blc  end
 142           cs   20          Clear entry link if first record
     *
     * Clear down to 300
     *
 143           sw   1,301
 144           sbr  cleer&3,begin-1
 145 cleer     cs   0-0
 146           sbr  cleer&3
 147           bw   cleer,301
 149           b    nutap
     *
 158 end       wtm  1
 159           rwd  1
 160           messg@1401 Fortran compiler generated on tu 1@,70,1,1
     eoj       nop  2222
 161           h
 162           b    eoj
     *
     * Write 80-character records without word marks for functions
     *
 163 funct     sw   erxt&4        Switch to return to lgm
 165 lgm       lca  @}@,80          gm
 166           wt   1,1
 167           ber  tperr
 168           c    4,@;;;;@      all 11-6-8
 169           be   ndfun
 170           r
 171           ssb  lgm,1
 172 ndfun     sw   1
 173           cw   80
 174           cw   erxt&4        Switch to return to put
 175           b    nutap
     *
     * Link to the start loaded into 1-14 of first rec
     *
 185           ber  010
 186           b    xbegin
 188           h    010
 189 fixed     dcw  0
 190 count     dcw  00
 191 trap      b    retrn
 193           end  begin
