return to main page

Demo-HZG.html

How about calling it the "HzG demo program",
since it was developed by our colleagues at the "Haus zur Geschichte der IBM Datenverarbeitung." (House of the History of IBM Data Processing.)
- Robert


from Van Snyder
December 14, 2007
Here are complete zip files for the HzG demo program, and my revision of it.

The control card layout is described in lines 106-122 of the Autocoder listing (exercise.asc or exercise.ps, the former being a plain-text Ascii file) in both zips.

The sense switches are described at lines 181-189 in the listing in exercise.nodisk.zip. The loop is the same, at a slightly different place in exercise.hzg, but without comments.

The files exercise*.s are the Autocoder source file.s

The file madonna.in has a control card, and then an Ascii image of Madonna and child and an "HzG souvenir" paragraph. One could keep the control card and replace the rest by the "CHM souvenir" paragraph.

Van

- Source deck
- Listing
- Object deck
- Madonna deck



 106         I3LEN  EQU   4    1-4     TAPE 3 RECORD LENGTH                           0004
 107         I3WMAX EQU   8    6-8     TAPE 3 RECORDS UNTIL REWIND                    0008
 108         I3PMAX EQU   11   10-11   TAPE 3 PROCESSING DELAY                        0011
 109         I3RDLY EQU   16   13-16   TAPE 3 REWIND DELAY                            0016
 110         I4LEN  EQU   21   18-21   TAPE 4 RECORD LENGTH                           0021
 111         I4WMAX EQU   25   23-25   TAPE 4 RECORDS UNTIL REWIND                    0025
 112         I4PMAX EQU   28   27-28   TAPE 4 PROCESSING DELAY                        0028
 113         I4RDLY EQU   33   30-33   TAPE 4 REWIND DELAY                            0033
 114         I5LEN  EQU   38   35-38   TAPE 5 RECORD LENGTH                           0038
 115         I5WMAX EQU   42   40-42   TAPE 5 RECORDS UNTIL REWIND                    0042
 116         I5PMAX EQU   45   44-45   TAPE 5 PROCESSING DELAY                        0045
 117         I5RDLY EQU   50   47-50   TAPE 5 REWIND DELAY                            0050
 118         I6LEN  EQU   55   52-55   TAPE 6 RECORD LENGTH                           0055
 119         I6WMAX EQU   59   57-59   TAPE 6 RECORDS UNTIL REWIND                    0059
 120         I6PMAX EQU   62   61-62   TAPE 6 PROCESSING DELAY                        0062
 121         I6RDLY EQU   67   64-67   TAPE 6 REWIND DELAY                            0067
 122         IRDLY  EQU   72   69-72   FULL REEL TAPE REWIND DELAY                    0072


 175         SWLOOP BSS   PRINT,C            D-MOD CHANGED BY PRINT TO BLANK       5  0428  B 519 C  
 176                BSS   TAPEX,D            EXERCISE TAPE 3                       5  0433  B 577 D 
 177         NOP    NOP   T3PAKT                                                   4  0438  N 845   
 178                BSS   TAPEX,E            EXERCISE TAPE 4                       5  0442  B 577 E  
 179                NOP   T4PAKT                                                   4  0447  N 873    
 180                BSS   TAPEX,F            EXERCISE TAPE 5                       5  0451  B 577 F 
 181                NOP   T5PAKT                                                   4  0456  N 901    
 182                BSS   TAPEX,G            EXERCISE TAPE 6                       5  0460  B 577 G  
 183                NOP   T6PAKT                                                   4  0465  N 929    
 184                B     SWLOOP                                                   4  0469  B 428   


 
---------------------------------------
exercise_nodisk.s
---------------------------------------


               JOB  HZG DEMO                                               SGSVU
               CTL  6611
     *
     * CONTROL CARD LAYOUT
     *
     I3LEN     EQU  4    1-4     TAPE 3 RECORD LENGTH
     I3WMAX    EQU  8    6-8     TAPE 3 RECORDS UNTIL REWIND
     I3PMAX    EQU  11   10-11   TAPE 3 PROCESSING DELAY
     I3RDLY    EQU  16   13-16   TAPE 3 REWIND DELAY
     I4LEN     EQU  21   18-21   TAPE 4 RECORD LENGTH
     I4WMAX    EQU  25   23-25   TAPE 4 RECORDS UNTIL REWIND
     I4PMAX    EQU  28   27-28   TAPE 4 PROCESSING DELAY
     I4RDLY    EQU  33   30-33   TAPE 4 REWIND DELAY
     I5LEN     EQU  38   35-38   TAPE 5 RECORD LENGTH
     I5WMAX    EQU  42   40-42   TAPE 5 RECORDS UNTIL REWIND
     I5PMAX    EQU  45   44-45   TAPE 5 PROCESSING DELAY
     I5RDLY    EQU  50   47-50   TAPE 5 REWIND DELAY
     I6LEN     EQU  55   52-55   TAPE 6 RECORD LENGTH
     I6WMAX    EQU  59   57-59   TAPE 6 RECORDS UNTIL REWIND
     I6PMAX    EQU  62   61-62   TAPE 6 PROCESSING DELAY
     I6RDLY    EQU  67   64-67   TAPE 6 REWIND DELAY
     IRDLY     EQU  72   69-72   FULL REEL TAPE REWIND DELAY
     *
               ORG  81           RECORD MARK AT 81 WILL BE
               DC   @'@          SENTINEL AFTER LAST LINE OF IMAGE
     KP1       DCW  &1
     KB        DCW  #1           CHANGES BSS C TO BRANCH
     KC        DCW  @C@          CHANGES BRANCH TO BSS C
               DC   @..@
     X1        DCW  081
               DC   @..@
     X2        DCW  010
               DC   @..@
     X3        DCW  000
     GMWM      DCW  @"@
               ORG  336
     *
     * LOAD PARAMETERS
     *
     START     R
               MCW  I3RDLY,T3RDLY      TAPE 3 REWIND DELAY
               MCW                     TAPE 3 PROCESSING DELAY
               MCW                     TAPE 3 RECORDS UNTIL REWIND
               MCW  I4RDLY,T4RDLY      TAPE 4 REWIND DELAY
               MCW                     TAPE 4 PROCESSING DELAY
               MCW                     TAPE 4 RECORDS UNTIL REWIND
               MCW  I5RDLY,T5RDLY      TAPE 5 REWIND DELAY
               MCW                     TAPE 5 PROCESSING DELAY
               MCW                     TAPE 5 RECORDS UNTIL REWIND
               MCW  I6RDLY,T6RDLY      TAPE 6 REWIND DELAY
               MCW                     TAPE 6 PROCESSING DELAY
               MCW                     TAPE 6 RECORDS UNTIL REWIND
               MCW  IRDLY,RDELAY       REWIND FULL TAPE DELAY COUNT
     *
     * CALCULATE TAPE WRITE ADDRESSES FROM RECORD LENGTHS
     *
               B    GETOFF             CALULATE OFFSET = - I3LEN
               DSA  I3LEN              TAPE 3 RECORD LENGTH
               DSA  TAPE3W&6           TAPE 3 WRITE INSTRUCTION
               B    GETOFF             CALULATE OFFSET = - I4LEN
               DSA  I4LEN              TAPE 4 RECORD LENGTH
               DSA  TAPE4W&6           TAPE 4 WRITE INSTRUCTION
               B    GETOFF             CALULATE OFFSET = - I5LEN
               DSA  I5LEN              TAPE 5 RECORD LENGTH
               DSA  TAPE5W&6           TAPE 5 WRITE INSTRUCTION
               B    GETOFF             CALULATE OFFSET = - I6LEN
               DSA  I6LEN              TAPE 6 RECORD LENGTH
               DSA  TAPE6W&6           TAPE 6 WRITE INSTRUCTION
     *
               SW   1
               B    RDIMAG             READ AND STORE THE IMAGE
     *
     * EVENT LOOP -- CHECK SWITCHES TO DETERMINE ACTIONS
     *
     SWLOOP    BSS  PRINT,C            D-MOD CHANGED BY PRINT TO BLANK
               BSS  TAPEX,D            EXERCISE TAPE 3
     NOP       NOP  T3PAKT
               BSS  TAPEX,E            EXERCISE TAPE 4
               NOP  T4PAKT
               BSS  TAPEX,F            EXERCISE TAPE 5
               NOP  T5PAKT
               BSS  TAPEX,G            EXERCISE TAPE 6
               NOP  T6PAKT
               B    SWLOOP
               JOB  HZG DEMO -- PRINT THE PICTURE                          SGSVU
     *
     * READ THE IMAGE AND STORE IT.  THE FIRST CHARACTER AFTER THE LAST
     * ONE IN THE STORAGE AREA WILL BE A RECORD MARK.
     *
     RDIMAG    SBR  RDEXIT&3
     RLOOP     R
               LCA  81,IMAGE&X1        STORE ONE LINE OF THE IMAGE
               B    GOTEM,A            DONE?
               SBR  X1,80&X1           ADD 80 TO X1
               B    RLOOP              GET ANOTHER ONE
     *
     GOTEM     SBR  X1,80              RESET X1 TO 80
               CS   332
               CS
               CC   1
     RDEXIT    H    0                  WAIT FOR THE SWITCHES TO BE SET
     *
     * PRINT THE PICTURE
     *
     PRINT     SBR  PRINTX&3
               MCW  KB,SWLOOP&4        MAKE ENTRY TEST UNCONDITIONAL
               LCA  IMAGE&X1,306
               W
               B    PRINTA,IMAGE&1&X1,'  LAST IMAGE?   
               SBR  X1,80&X1           ADD 80 TO X1
               B    PRINTX
     PRINTA    SBR  X1,80              RESET X1 TO 80
               CC   1
               MCW  KC,SWLOOP&4        CHANGE ENTRY TEST TO BSS C
     PRINTX    B    0
               JOB  HZG DEMO -- TAPE EXERCISER                             SGSVU
     *
     * TAPE EXERCISER PACKET LAYOUT
     *
     TWMAX     EQU  2&X3    NUMBER OF RECORDS INITIAL VALUE
     TPMAX     EQU  5&X3    PROCESSING DELAY INITIAL VALUE
     TRDLY     EQU  10&X3   REWIND DELAY INITIAL VALUE
     TWRIT     EQU  18&X3   TAPE WRITE INSTRUCTION LAST CHAR
     TPCNT     EQU  20&X3   CURRENT PROCESSING DELAY COUNT
     TWCNT     EQU  23&X3   CURRENT RECORDS UNTIL REWIND
     TRCNT     EQU  27&X3   CURRENT REWIND DELAY COUNT
     *
     * TAPE EXERCISER.  FOLLOW  B TAPEX  WITH  NOP PACKET
     *
     TAPEX     SBR  TAPEXX&3
               SBR  X3
               MCW  4&X3,X3            ADDRESS OF PACKET TO X3
               BWZ  TAPEXA,TRCNT,K     ENOUGH REWIND DELAY?
               S    KP1,TRCNT
               B    TAPEXX
     TAPEXA    C    KONE,TPCNT         ENOUGH PROCESSING DELAY?
               BE   TAPEXB
               S    KP1,TPCNT          DECR PROCESSING DELAY COUNT
               MZ   KZERO,TPCNT
               B    TAPEXX
     TAPEXB    LCA  TRDLY,TRCNT        RWD DELAY DEPENDING ON REC CNT
               BWZ  TAPEXE,TWCNT,K     TIME TO REWIND?
               LCA  RDELAY,TRCNT       DELAY FOR FULL REEL REWIND
               BEF  TAPEXE
               LCA  KM1,TRCNT          SET FOR NO REWIND DELAY
               MCW  TWRIT,*&8          COPY TAPE WRITE INSTRUCTION
               WT   3,GMWM
               S    KP1,TWCNT          DECREMENT WRITE COUNTER
               MCW  TPMAX,TPCNT        STORE PROCESSING DELAY
     TAPEXX    B    0
     TAPEXE    MN   TWRIT-4,*&4        SET DRIVE NUMBER IN REWIND
               RWD  3
               MCW  TWMAX,TWCNT        RE-INITIALIZE WRITE COUNT
               B    TAPEXX
     *
     * OFFSET THE TAPE WRITE ADDRESS, GIVEN THE RECORD LENGTH
     * DO THIS BY MA-ING THE 16000-COMPLEMENT OF THE RECORD
     * LENGTH TO THE ADDRESS IN THE TAPE WRITE INSTRUCTION
     *
     GETOFF    SBR  X3
               SBR  GETXX&3,6&X3
               LCA  P16K,ROFF          START WITH 16001
               MCW  2&X3,*&4           ADDRESS OF RECORD LENGTH
               S    0,ROFF             DECREASE BY RECORD LENGTH
               MZ   KZERO,ROFF         CLEAR ZONE
     GETL      S    KP1,RTHOU
               BWZ  GETX,RTHOU,K       DONE?
               MA   K1000,ROFF         ADD 1000 TO OFFSET
               B    GETL 
     GETX      MCW  5&X3,X3            ADDRESS OF TAPE WRITE
               CS   0                  GET LAST ADDRESS TO B REG
               LCA  GMWM               GMWM TO TOP OF MEMORY
               SBR  0&X3               LAST ADDRESS IN MEMORY - 1
               MA   ROFF,0&X3          SUBTRACT RECORD LENGTH
     GETXX     B    0
     *
     RLEN      DCW  0000               RECORD LENGTH
     RTHOU     DCW  00                 THOUSANDS PART OF OFFSET
     ROFF      DC   000                OFFSET TO TAPE ADDRESS = - RLEN
     K1000     DSA  1000               ADDRESS CONSTANT 1000
     P16K      DCW  16001
     *
     * TAPE EXERCISER CONTROL PACKETS
     *
     T3PAKT    DCW  000     NUMBER OF RECORDS INITIAL VALUE
               DC   #1      FILLER FROM CONTROL CARD
               DCW  00      PROCESSING DELAY INITIAL VALUE
               DC   #1      FILLER FROM CONTROL CARD
     T3RDLY    DCW  0000    REWIND DELAY INITIAL VALUE
     TAPE3W    WT   3,0     TAPE WRITE INSTRUCTION
               DCW  00      CURRENT PROCESSING DELAY COUNT
               DCW  000     CURRENT RECORDS UNTIL REWIND
               DCW  -0001   CURRENT REWIND DELAY COUNT
     *
     T4PAKT    DCW  000     NUMBER OF RECORDS INITIAL VALUE
               DC   #1      FILLER FROM CONTROL CARD
               DCW  00      PROCESSING DELAY INITIAL VALUE
               DC   #1      FILLER FROM CONTROL CARD
     T4RDLY    DCW  0000    REWIND DELAY INITIAL VALUE
     TAPE4W    WT   4,0     TAPE WRITE INSTRUCTION
               DCW  00      CURRENT PROCESSING DELAY COUNT
               DCW  000     CURRENT RECORDS UNTIL REWIND
               DCW  -0001   CURRENT REWIND DELAY COUNT
     *
     T5PAKT    DCW  000     NUMBER OF RECORDS INITIAL VALUE
               DC   #1      FILLER FROM CONTROL CARD
               DCW  00      PROCESSING DELAY INITIAL VALUE
               DC   #1      FILLER FROM CONTROL CARD
     T5RDLY    DCW  0000    REWIND DELAY INITIAL VALUE
     TAPE5W    WT   5,0     TAPE WRITE INSTRUCTION
               DCW  00      CURRENT PROCESSING DELAY COUNT
               DCW  000     CURRENT RECORDS UNTIL REWIND
               DCW  -0001   CURRENT REWIND DELAY COUNT
     *
     T6PAKT    DCW  000     NUMBER OF RECORDS INITIAL VALUE
               DC   #1      FILLER FROM CONTROL CARD
               DCW  00      PROCESSING DELAY INITIAL VALUE
               DC   #1      FILLER FROM CONTROL CARD
     T6RDLY    DCW  0000    REWIND DELAY INITIAL VALUE
     TAPE6W    WT   6,0     TAPE WRITE INSTRUCTION
               DCW  00      CURRENT PROCESSING DELAY COUNT
               DCW  000     CURRENT RECORDS UNTIL REWIND
               DCW  -0001   CURRENT REWIND DELAY COUNT
     *
     RDELAY    DCW  0000    DELAY COUNTER FOR EOT REWINDS
     KM1       DCW  -0001   CONSTANT -1
     *
     KZERO     DCW  000                CONSTANT ZERO
     KONE      DCW  001
     IMAGE     DS   1       STORAGE FOR IMAGE STARTS HERE
               END  START



---------------------------------------
exercise_nodisk.asc  same as exercise_nodisk.lst
---------------------------------------


CLEAR STORAGE 1     ,008015,022026,030037,044,049,053053N000000N00001026                                         1
CLEAR STORAGE 2     L068116,105106,110117B101/I9I#071029C029056B026/B001/0991,001/001117I0?                      2
BOOTSTRAP           ,008015,022029,036040,047054,061068,072/061039              ,0010011040                      3

                          HZG DEMO                                                   SGSVU               PAGE    1

 SEQ PG LIN  LABEL  OP    OPERANDS                                            SFX CT  LOCN  INSTRUCTION TYPE  CARD

 101                JOB   HZG DEMO
 102                CTL   6611
 103         *
 104         * CONTROL CARD LAYOUT
 105         *
 106         I3LEN  EQU   4    1-4     TAPE 3 RECORD LENGTH                           0004
 107         I3WMAX EQU   8    6-8     TAPE 3 RECORDS UNTIL REWIND                    0008
 108         I3PMAX EQU   11   10-11   TAPE 3 PROCESSING DELAY                        0011
 109         I3RDLY EQU   16   13-16   TAPE 3 REWIND DELAY                            0016
 110         I4LEN  EQU   21   18-21   TAPE 4 RECORD LENGTH                           0021
 111         I4WMAX EQU   25   23-25   TAPE 4 RECORDS UNTIL REWIND                    0025
 112         I4PMAX EQU   28   27-28   TAPE 4 PROCESSING DELAY                        0028
 113         I4RDLY EQU   33   30-33   TAPE 4 REWIND DELAY                            0033
 114         I5LEN  EQU   38   35-38   TAPE 5 RECORD LENGTH                           0038
 115         I5WMAX EQU   42   40-42   TAPE 5 RECORDS UNTIL REWIND                    0042
 116         I5PMAX EQU   45   44-45   TAPE 5 PROCESSING DELAY                        0045
 117         I5RDLY EQU   50   47-50   TAPE 5 REWIND DELAY                            0050
 118         I6LEN  EQU   55   52-55   TAPE 6 RECORD LENGTH                           0055
 119         I6WMAX EQU   59   57-59   TAPE 6 RECORDS UNTIL REWIND                    0059
 120         I6PMAX EQU   62   61-62   TAPE 6 PROCESSING DELAY                        0062
 121         I6RDLY EQU   67   64-67   TAPE 6 REWIND DELAY                            0067
 122         IRDLY  EQU   72   69-72   FULL REEL TAPE REWIND DELAY                    0072
 123         *
 124                ORG   81           RECORD MARK AT 81 WILL BE                             0081
 125                DC    @'@          SENTINEL AFTER LAST LINE OF IMAGE           1  0081                       4
 126         KP1    DCW   &1                                                       1  0082                       4
 127         KB     DCW   #1           CHANGES BSS C TO BRANCH                     1  0083                       4
 128         KC     DCW   @C@          CHANGES BRANCH TO BSS C                     1  0084                       4
 129                DC    @..@                                                     2  0086                       4
 130         X1     DCW   081                                                      3  0089                       4
 131                DC    @..@                                                     2  0091                       4
 132         X2     DCW   010                                                      3  0094                       5
 133                DC    @..@                                                     2  0096                       5
 134         X3     DCW   000                                                      3  0099                       5
 135         GMWM   DCW   @"@                                                      1  0100              GMARK    5
 136                ORG   336                                                                0336
 137         *
 138         * LOAD PARAMETERS
 139         *
 140         START  R                                                              1  0336  1                    6
 141                MCW   I3RDLY,T3RDLY      TAPE 3 REWIND DELAY                   7  0337  M 016 853            6
 142                MCW                      TAPE 3 PROCESSING DELAY               1  0344  M                    6
 143                MCW                      TAPE 3 RECORDS UNTIL REWIND           1  0345  M                    6
 144                MCW   I4RDLY,T4RDLY      TAPE 4 REWIND DELAY                   7  0346  M 033 881            6
 145                MCW                      TAPE 4 PROCESSING DELAY               1  0353  M                    6
 146                MCW                      TAPE 4 RECORDS UNTIL REWIND           1  0354  M                    6
 147                MCW   I5RDLY,T5RDLY      TAPE 5 REWIND DELAY                   7  0355  M 050 909            7
                          HZG DEMO                                                   SGSVU               PAGE    2

 SEQ PG LIN  LABEL  OP    OPERANDS                                            SFX CT  LOCN  INSTRUCTION TYPE  CARD

 148                MCW                      TAPE 5 PROCESSING DELAY               1  0362  M                    7
 149                MCW                      TAPE 5 RECORDS UNTIL REWIND           1  0363  M                    7
 150                MCW   I6RDLY,T6RDLY      TAPE 6 REWIND DELAY                   7  0364  M 067 937            7
 151                MCW                      TAPE 6 PROCESSING DELAY               1  0371  M                    7
 152                MCW                      TAPE 6 RECORDS UNTIL REWIND           1  0372  M                    7
 153                MCW   IRDLY,RDELAY       REWIND FULL TAPE DELAY COUNT          7  0373  M 072 958            7
 154         *
 155         * CALCULATE TAPE WRITE ADDRESSES FROM RECORD LENGTHS
 156         *
 157                B     GETOFF             CALULATE OFFSET = - I3LEN             4  0380  B 731                8
 158                DSA   I3LEN              TAPE 3 RECORD LENGTH                  3  0386  004                  8
 159                DSA   TAPE3W&6           TAPE 3 WRITE INSTRUCTION              3  0389  860                  8
 160                B     GETOFF             CALULATE OFFSET = - I4LEN             4  0390  B 731                8
 161                DSA   I4LEN              TAPE 4 RECORD LENGTH                  3  0396  021                  8
 162                DSA   TAPE4W&6           TAPE 4 WRITE INSTRUCTION              3  0399  888                  8
 163                B     GETOFF             CALULATE OFFSET = - I5LEN             4  0400  B 731                8
 164                DSA   I5LEN              TAPE 5 RECORD LENGTH                  3  0406  038                  9
 165                DSA   TAPE5W&6           TAPE 5 WRITE INSTRUCTION              3  0409  916                  9
 166                B     GETOFF             CALULATE OFFSET = - I6LEN             4  0410  B 731                9
 167                DSA   I6LEN              TAPE 6 RECORD LENGTH                  3  0416  055                  9
 168                DSA   TAPE6W&6           TAPE 6 WRITE INSTRUCTION              3  0419  944                  9
 169         *
 170                SW    1                                                        4  0420  , 001                9
 171                B     RDIMAG             READ AND STORE THE IMAGE              4  0424  B 473                9
 172         *
 173         * EVENT LOOP -- CHECK SWITCHES TO DETERMINE ACTIONS
 174         *
 175         SWLOOP BSS   PRINT,C            D-MOD CHANGED BY PRINT TO BLANK       5  0428  B 519 C             10
 176                BSS   TAPEX,D            EXERCISE TAPE 3                       5  0433  B 577 D             10
 177         NOP    NOP   T3PAKT                                                   4  0438  N 845               10
 178                BSS   TAPEX,E            EXERCISE TAPE 4                       5  0442  B 577 E             10
 179                NOP   T4PAKT                                                   4  0447  N 873               10
 180                BSS   TAPEX,F            EXERCISE TAPE 5                       5  0451  B 577 F             10
 181                NOP   T5PAKT                                                   4  0456  N 901               10
 182                BSS   TAPEX,G            EXERCISE TAPE 6                       5  0460  B 577 G             11
 183                NOP   T6PAKT                                                   4  0465  N 929               11
 184                B     SWLOOP                                                   4  0469  B 428               11
                          HZG DEMO -- PRINT THE PICTURE                              SGSVU               PAGE    3

 SEQ PG LIN  LABEL  OP    OPERANDS                                            SFX CT  LOCN  INSTRUCTION TYPE  CARD

 185                JOB   HZG DEMO -- PRINT THE PICTURE
 186         *
 187         * READ THE IMAGE AND STORE IT.  THE FIRST CHARACTER AFTER THE LAST
 188         * ONE IN THE STORAGE AREA WILL BE A RECORD MARK.
 189         *
 190         RDIMAG SBR   RDEXIT&3                                                 4  0473  H 518               12
 191         RLOOP  R                                                              1  0477  1                   12
 192                LCA   81,IMAGE&X1        STORE ONE LINE OF THE IMAGE           7  0478  L 081 9W9           12
 193                B     GOTEM,A            DONE?                                 5  0485  B 501 A             12
 194                SBR   X1,80&X1           ADD 80 TO X1                          7  0490  H 089 0Y0           12
 195                B     RLOOP              GET ANOTHER ONE                       4  0497  B 477               12
 196         *
 197         GOTEM  SBR   X1,80              RESET X1 TO 80                        7  0501  H 089 080           12
 198                CS    332                                                      4  0508  / 332               13
 199                CS                                                             1  0512  /                   13
 200                CC    1                                                        2  0513  F 1                 13
 201         RDEXIT H     0                  WAIT FOR THE SWITCHES TO BE SET       4  0515  . 000               13
 202         *
 203         * PRINT THE PICTURE
 204         *
 205         PRINT  SBR   PRINTX&3                                                 4  0519  H 576               13
 206                MCW   KB,SWLOOP&4        MAKE ENTRY TEST UNCONDITIONAL         7  0523  M 083 432           13
 207                LCA   IMAGE&X1,306                                             7  0530  L 9W9 306           13
 208                W                                                              1  0537  2                   14
 209                B     PRINTA,IMAGE&1&X1,'  LAST IMAGE?                         8  0538  B 557 9X0 '         14
 210                SBR   X1,80&X1           ADD 80 TO X1                          7  0546  H 089 0Y0           14
 211                B     PRINTX                                                   4  0553  B 573               14
 212         PRINTA SBR   X1,80              RESET X1 TO 80                        7  0557  H 089 080           14
 213                CC    1                                                        2  0564  F 1                 14
 214                MCW   KC,SWLOOP&4        CHANGE ENTRY TEST TO BSS C            7  0566  M 084 432           14
 215         PRINTX B     0                                                        4  0573  B 000               15
                          HZG DEMO -- TAPE EXERCISER                                 SGSVU               PAGE    4

 SEQ PG LIN  LABEL  OP    OPERANDS                                            SFX CT  LOCN  INSTRUCTION TYPE  CARD

 216                JOB   HZG DEMO -- TAPE EXERCISER
 217         *
 218         * TAPE EXERCISER PACKET LAYOUT
 219         *
 220         TWMAX  EQU   2&X3    NUMBER OF RECORDS INITIAL VALUE                     0002 X
 221         TPMAX  EQU   5&X3    PROCESSING DELAY INITIAL VALUE                      0005 X
 222         TRDLY  EQU   10&X3   REWIND DELAY INITIAL VALUE                          0010 X
 223         TWRIT  EQU   18&X3   TAPE WRITE INSTRUCTION LAST CHAR                    0018 X
 224         TPCNT  EQU   20&X3   CURRENT PROCESSING DELAY COUNT                      0020 X
 225         TWCNT  EQU   23&X3   CURRENT RECORDS UNTIL REWIND                        0023 X
 226         TRCNT  EQU   27&X3   CURRENT REWIND DELAY COUNT                          0027 X
 227         *
 228         * TAPE EXERCISER.  FOLLOW  B TAPEX  WITH  NOP PACKET
 229         *
 230         TAPEX  SBR   TAPEXX&3                                                 4  0577  H 707               16
 231                SBR   X3                                                       4  0581  H 099               16
 232                MCW   4&X3,X3            ADDRESS OF PACKET TO X3               7  0585  M 0?4 099           16
 233                BWZ   TAPEXA,TRCNT,K     ENOUGH REWIND DELAY?                  8  0592  V 611 0B7 K         16
 234                S     KP1,TRCNT                                                7  0600  S 082 0B7           16
 235                B     TAPEXX                                                   4  0607  B 704               16
 236         TAPEXA C     KONE,TPCNT         ENOUGH PROCESSING DELAY?              7  0611  C 968 0B0           17
 237                BE    TAPEXB                                                   5  0618  B 641 S             17
 238                S     KP1,TPCNT          DECR PROCESSING DELAY COUNT           7  0623  S 082 0B0           17
 239                MZ    KZERO,TPCNT                                              7  0630  Y 965 0B0           17
 240                B     TAPEXX                                                   4  0637  B 704               17
 241         TAPEXB LCA   TRDLY,TRCNT        RWD DELAY DEPENDING ON REC CNT        7  0641  L 0A0 0B7           17
 242                BWZ   TAPEXE,TWCNT,K     TIME TO REWIND?                       8  0648  V 708 0B3 K         18
 243                LCA   RDELAY,TRCNT       DELAY FOR FULL REEL REWIND            7  0656  L 958 0B7           18
 244                BEF   TAPEXE                                                   5  0663  B 708 K             18
 245                LCA   KM1,TRCNT          SET FOR NO REWIND DELAY               7  0668  L 962 0B7           18
 246                MCW   TWRIT,*&8          COPY TAPE WRITE INSTRUCTION           7  0675  M 0A8 689           18
 247                WT    3,GMWM                                                   8  0682  M %U3 100 W         19
 248                S     KP1,TWCNT          DECREMENT WRITE COUNTER               7  0690  S 082 0B3           19
 249                MCW   TPMAX,TPCNT        STORE PROCESSING DELAY                7  0697  M 0?5 0B0           19
 250         TAPEXX B     0                                                        4  0704  B 000               19
 251         TAPEXE MN    TWRIT-4,*&4        SET DRIVE NUMBER IN REWIND            7  0708  D 0A4 718           19
 252                RWD   3                                                        5  0715  U %U3 R             19
 253                MCW   TWMAX,TWCNT        RE-INITIALIZE WRITE COUNT             7  0720  M 0?2 0B3           20
 254                B     TAPEXX                                                   4  0727  B 704               20
 255         *
 256         * OFFSET THE TAPE WRITE ADDRESS, GIVEN THE RECORD LENGTH
 257         * DO THIS BY MA-ING THE 16000-COMPLEMENT OF THE RECORD
 258         * LENGTH TO THE ADDRESS IN THE TAPE WRITE INSTRUCTION
 259         *
 260         GETOFF SBR   X3                                                       4  0731  H 099               20
 261                SBR   GETXX&3,6&X3                                             7  0735  H 825 0?6           20
 262                LCA   P16K,ROFF          START WITH 16001                      7  0742  L 842 834           20
 263                MCW   2&X3,*&4           ADDRESS OF RECORD LENGTH              7  0749  M 0?2 759           20
 264                S     0,ROFF             DECREASE BY RECORD LENGTH             7  0756  S 000 834           21
 265                MZ    KZERO,ROFF         CLEAR ZONE                            7  0763  Y 965 834           21
                          HZG DEMO -- TAPE EXERCISER                                 SGSVU               PAGE    5

 SEQ PG LIN  LABEL  OP    OPERANDS                                            SFX CT  LOCN  INSTRUCTION TYPE  CARD

 266         GETL   S     KP1,RTHOU                                                7  0770  S 082 831           21
 267                BWZ   GETX,RTHOU,K       DONE?                                 8  0777  V 796 831 K         21
 268                MA    K1000,ROFF         ADD 1000 TO OFFSET                    7  0785  # 837 834           21
 269                B     GETL                                                     4  0792  B 770               22
 270         GETX   MCW   5&X3,X3            ADDRESS OF TAPE WRITE                 7  0796  M 0?5 099           22
 271                CS    0                  GET LAST ADDRESS TO B REG             4  0803  / 000               22
 272                LCA   GMWM               GMWM TO TOP OF MEMORY                 4  0807  L 100               22
 273                SBR   0&X3               LAST ADDRESS IN MEMORY - 1            4  0811  H 0?0               22
 274                MA    ROFF,0&X3          SUBTRACT RECORD LENGTH                7  0815  # 834 0?0           22
 275         GETXX  B     0                                                        4  0822  B 000               22
 276         *
 277         RLEN   DCW   0000               RECORD LENGTH                         4  0829                      23
 278         RTHOU  DCW   00                 THOUSANDS PART OF OFFSET              2  0831                      23
 279         ROFF   DC    000                OFFSET TO TAPE ADDRESS = - RLEN       3  0834                      23
 280         K1000  DSA   1000               ADDRESS CONSTANT 1000                 3  0837  '00                 23
 281         P16K   DCW   16001                                                    5  0842                      23
 282         *
 283         * TAPE EXERCISER CONTROL PACKETS
 284         *
 285         T3PAKT DCW   000     NUMBER OF RECORDS INITIAL VALUE                  3  0845                      23
 286                DC    #1      FILLER FROM CONTROL CARD                         1  0846                      23
 287                DCW   00      PROCESSING DELAY INITIAL VALUE                   2  0848                      23
 288                DC    #1      FILLER FROM CONTROL CARD                         1  0849                      23
 289         T3RDLY DCW   0000    REWIND DELAY INITIAL VALUE                       4  0853                      23
 290         TAPE3W WT    3,0     TAPE WRITE INSTRUCTION                           8  0854  M %U3 000 W         24
 291                DCW   00      CURRENT PROCESSING DELAY COUNT                   2  0863                      24
 292                DCW   000     CURRENT RECORDS UNTIL REWIND                     3  0866                      24
 293                DCW   -0001   CURRENT REWIND DELAY COUNT                       4  0870                      24
 294         *
 295         T4PAKT DCW   000     NUMBER OF RECORDS INITIAL VALUE                  3  0873                      24
 296                DC    #1      FILLER FROM CONTROL CARD                         1  0874                      24
 297                DCW   00      PROCESSING DELAY INITIAL VALUE                   2  0876                      24
 298                DC    #1      FILLER FROM CONTROL CARD                         1  0877                      24
 299         T4RDLY DCW   0000    REWIND DELAY INITIAL VALUE                       4  0881                      24
 300         TAPE4W WT    4,0     TAPE WRITE INSTRUCTION                           8  0882  M %U4 000 W         25
 301                DCW   00      CURRENT PROCESSING DELAY COUNT                   2  0891                      25
 302                DCW   000     CURRENT RECORDS UNTIL REWIND                     3  0894                      25
 303                DCW   -0001   CURRENT REWIND DELAY COUNT                       4  0898                      25
 304         *
 305         T5PAKT DCW   000     NUMBER OF RECORDS INITIAL VALUE                  3  0901                      25
 306                DC    #1      FILLER FROM CONTROL CARD                         1  0902                      25
 307                DCW   00      PROCESSING DELAY INITIAL VALUE                   2  0904                      25
 308                DC    #1      FILLER FROM CONTROL CARD                         1  0905                      25
 309         T5RDLY DCW   0000    REWIND DELAY INITIAL VALUE                       4  0909                      25
 310         TAPE5W WT    5,0     TAPE WRITE INSTRUCTION                           8  0910  M %U5 000 W         26
 311                DCW   00      CURRENT PROCESSING DELAY COUNT                   2  0919                      26
 312                DCW   000     CURRENT RECORDS UNTIL REWIND                     3  0922                      26
 313                DCW   -0001   CURRENT REWIND DELAY COUNT                       4  0926                      26
 314         *
 315         T6PAKT DCW   000     NUMBER OF RECORDS INITIAL VALUE                  3  0929                      26
                          HZG DEMO -- TAPE EXERCISER                                 SGSVU               PAGE    6

 SEQ PG LIN  LABEL  OP    OPERANDS                                            SFX CT  LOCN  INSTRUCTION TYPE  CARD

 316                DC    #1      FILLER FROM CONTROL CARD                         1  0930                      26
 317                DCW   00      PROCESSING DELAY INITIAL VALUE                   2  0932                      26
 318                DC    #1      FILLER FROM CONTROL CARD                         1  0933                      26
 319         T6RDLY DCW   0000    REWIND DELAY INITIAL VALUE                       4  0937                      26
 320         TAPE6W WT    6,0     TAPE WRITE INSTRUCTION                           8  0938  M %U6 000 W         27
 321                DCW   00      CURRENT PROCESSING DELAY COUNT                   2  0947                      27
 322                DCW   000     CURRENT RECORDS UNTIL REWIND                     3  0950                      27
 323                DCW   -0001   CURRENT REWIND DELAY COUNT                       4  0954                      27
 324         *
 325         RDELAY DCW   0000    DELAY COUNTER FOR EOT REWINDS                    4  0958                      27
 326         KM1    DCW   -0001   CONSTANT -1                                      4  0962                      27
 327         *
 328         KZERO  DCW   000                CONSTANT ZERO                         3  0965                      27
 329         KONE   DCW   001                                                      3  0968                      28
 330         IMAGE  DS    1       STORAGE FOR IMAGE STARTS HERE                       0969
 331                END   START                                                             / 336 080
                          HZG DEMO -- TAPE EXERCISER                                 SGSVU               PAGE    7

SYMBOL  ADDRESS  SYMBOL  ADDRESS  SYMBOL  ADDRESS  SYMBOL  ADDRESS  SYMBOL  ADDRESS  SYMBOL  ADDRESS  SYMBOL  ADDRESS  
GETL      770    GETOFF    731    GETX      796    GETXX     822    GMWM      100    GOTEM     501    I3LEN       4   
I3PMAX     11    I3RDLY     16    I3WMAX      8    I4LEN      21    I4PMAX     28    I4RDLY     33    I4WMAX     25   
I5LEN      38    I5PMAX     45    I5RDLY     50    I5WMAX     42    I6LEN      55    I6PMAX     62    I6RDLY     67   
I6WMAX     59    IMAGE     969    IRDLY      72    K1000     837    KB         83    KC         84    KM1       962   
KONE      968    KP1        82    KZERO     965    NOP       438    P16K      842    PRINT     519    PRINTA    557   
PRINTX    573    RDELAY    958    RDEXIT    515    RDIMAG    473    RLEN      829    RLOOP     477    ROFF      834   
RTHOU     831    START     336    SWLOOP    428    T3PAKT    845    T3RDLY    853    T4PAKT    873    T4RDLY    881   
T5PAKT    901    T5RDLY    909    T6PAKT    929    T6RDLY    937    TAPE3W    854    TAPE4W    882    TAPE5W    910   
TAPE6W    938    TAPEX     577    TAPEXA    611    TAPEXB    641    TAPEXE    708    TAPEXX    704    TPCNT      20+X3
TPMAX       5+X3 TRCNT      27+X3 TRDLY      10+X3 TWCNT      23+X3 TWMAX       2+X3 TWRIT      18+X3 X1         89   
X2         94    X3         99   



---------------------------------------
exercise_nodisk.s
---------------------------------------


,008015,022026,030037,044,049,053053N000000N00001026                   0001SGSVU
L068116,105106,110117B101/I9I#071029C029056B026/B001/0991,001/001117I0?0002SGSVU
,008015,022029,036040,047054,061068,072/061039              ,00100110400003SGSVU
'A C..081..                            L011091)081081,082083,08408710400004SGSVU
010..000"                              L009100,097100,040040,04004010400005SGSVU
1M016853MMM033881MM                    L019354,337344,345346,35335410400006SGSVU
M050909MMM067937MMM072958              L025379,362363,364371,37237310400007SGSVU
B731004860B731021888B731               L024403,384387,390394,39740010400008SGSVU
038916B731055944,001B473               L024427,407410,414417,42042410400009SGSVU
B519CB577DN845B577EN873B577FN901       L032459,433438,442447,45145610400010SGSVU
B577GN929B428                          L013472,465469,040040,04004010400011SGSVU
H5181L0819W9B501AH0890Y0B477H089080    L035507,477478,485490,49750110400012SGSVU
/332/F1.000H576M083432L9W9306          L029536,512513,515519,52353010400013SGSVU
2B5579X0'H0890Y0B573H089080F1M084432   L036572,538546,553557,56456610400014SGSVU
B000                                   L004576,040040,040040,04004010400015SGSVU
H707H099M0?4099V6110B7KS0820B7B704     L034610,581585,592600,60704010400016SGSVU
C9680B0B641SS0820B0Y9650B0B704L0A00B7  L037647,618623,630637,64104010400017SGSVU
V7080B3KL9580B7B708KL9620B7M0A8689     L034681,656663,668675,04004010400018SGSVU
M%U3100WS0820B3M0?50B0B000D0A4718U%U3R L038719,690697,704708,71504010400019SGSVU
M0?20B3B704H099H8250?6L842834M0?2759   L036755,727731,735742,74904010400020SGSVU
S000834Y965834S082831V796831K#837834   L036791,763770,777785,04004010400021SGSVU
B770M0?5099/000L100H0?0#8340?0B000     L034825,796803,807811,81582210400022SGSVU
000000000'0016001000 00 0000           L028853,830835,838843,84785010400023SGSVU
M%U3000W00000000J000 00 0000           L028881,862864,867871,87587810400024SGSVU
M%U4000W00000000J000 00 0000           L028909,890892,895899,90390610400025SGSVU
M%U5000W00000000J000 00 0000           L028937,918920,923927,93193410400026SGSVU
M%U6000W00000000J0000000J000           L028965,946948,951955,95996310400027SGSVU
001                                    L003968,040040,040040,04004010400028SGSVU
                                       /336080                         0029SGSVU



 
---------------------------------------
Madonna deck
---------------------------------------


0500,999,09,0750/1000,720,22,0750/3000,660,43,0750/4000,370,81,0750/1700/70
    MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
    MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
    MMMMMMMMMMMMMMMMMMMMMMMMMMMMHHHHH11111HHHHMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
    MMMMMMMMMMMMMMMMMMMMMMMMMMH1................11MHMMMMMMMMMMMMMMMMMMMMMMM
    MMMMMMMMMMMMMMMMMMMMMMMMMH.....           ....111HHMMMMMMMMMMMMMMMMMMMM
    MMMMMMMMMMMMMMMMMMMMHHHH....H11....           .....1MMMMMMMMMMMMMMMMMMM
    MMMMMMMMMMMMMMMMMMMMHH...1HHHH1111..               ...HHMMMMMMMMMMMMMMM
    MMMMMMMMMMMMMMMMMMHH....H1111..11HH...              ....11MMMMMMMMMMMMM
    MMMMMMMMMMMMMMMMMH.....111...11H....HH...              .....HHMMMMMMMMM
    MMMMMMMMMMMMMMHHH....111..1HH1HH1....HH....            .....HHMMMMMMMMM
    MMMMMMMMMMMMMMH.../1HH11HHH1MMMMH.HHH11HH...              -..HHMMMMMMMM
    MMMMMMMMMMMMMH.....HHHH..11H1HMMM1..1HH.111H..8           ....1MMMMMMMM
    MMMMMMMMMMMMMH...H111111 ..11  1 .....111MM11.          .......MMMMMMMM
    MMMMMMMMMMMH...HHH1111 .. ..1HMMM.  .. MMMMHM..         ......1MMMMMMMM
    MMMMMMMMMMMH.1HHHH..   1  .11HM1. ......HHHMMMH...      .....  .1MMMMMM
    MMMMMMMMMMH..1HHHH  11H1H11HHMM11MMM11HHHHHHMMH....    ...     ..MMMMMM
    MMMMMMMMMMMH..H11HH1H11M1HHHMMH1HMMMHHHH1.....MMH1..    .        ..MMMM
    MMMMMMMMMH.. 11H.. HH1MMMHHMMH1111.....      .MMMH.             ..HMMMM
    MMMMMMMMMH.. 1HH..111. .1111.....             ..MM1.            .1MMMMM
    MMMMMMMMMH.  .HMH....                           .MM1..         ...HMMMM
    MMMMMMMMMH.  .HMH....                           ..MM1..         .1HMMMM
    MMMMMMMMMH. ..HMH....                            .MMM1..)       ...1HMM
    MMMMMMMHH. ...HM1....                             MMM1...     .....1HMM
    MMMMMMMHHH ...HH1....                             ...MM1..1    ..  .1MM
    MMMMMMMHH..  .1HM...                               .MMM1..    ... .. MM
    MMMMMMMH...   $.MM....                                .1MMM..    .1.MMM
    MMMMMMH....   .MM....                  ...LHHH... 7    1MM1..    .. MMM
    MMMMMMH...    .MM.....              ..HHHLL            1MH 1.      1.MM
    MMMMMMH...    .MM1.11HHH..         .......HLL...        1 H..     .. MM
    MMMMMM...    1MMH....LHHHHH.        ...H666***         .H  1      ..1MM
    MMMMMMM...    HMMH...H6*64/..     .HL.LL/            .  .H.    ...   MM
    MMMMM1....   .HMMM...1L.L.L1.H1.                           K1H.     .MM
    M..... ..1 ..1MMM1.  ..       ..                          .HM1. .    MM
    MMMMM...... .H1HHH..         ..                         .1MHHH.  1   MM
    MMMM.......  .1MMH....      1...                         HMMH1.8  .. MM
    MMM.........   .HMH....      ...        8               .1HHH11.  . .MM
    MMM.. .....     .HH1...      ...       .                .HHHH11..   .MM
    MMM.. .......    .HH.....   .....   ...                ..HMMHH11.   .MM
    MMM.. ........     .1........1H.. ..                   ..HMMMH11..   MM
    MMM..........1.   ..HV..........L.                    .HMMMMHH11.    MM
    MMM...........   ..1H.......     .......*          ..1HMMMMMH11.     MM
    MMMM.........111   ..1MH.....LHHHHL....              ..1HMMMMMH11.   MM
    MMMMM..     ..LHHH.. ...11.....1H1.......11111.          ..1111111111MM
    MMMM.......11111  ....HMMH1.....1HL......             .....HMMMMH1.. MM
    MMMM......111.11. ..11HMMH1...........                    ....HHH..  MM
    MMMMM....    ..1H..11HHMMHHH......            ..          .1111111111MM
    MMMMM...     ..HH1.11HHHHHMMMM.....       .....         .11111111111 MM
    MMMMM..     ...HH1111..1HHHMMMM1...........11..        2..1111111111 MM
    MMMMM.   ..11B1B1........B.....1..WWWWWWWW...        ..11111111111111MM
    MMH.   ....1H.. . .    .. 1H.. ....1. ..H11..          ..111111111111MM
    MH1.  ....H........1...  .H1H MMH.... ...11..         111111111111111MM
    H1   ....1 ...1H111HH1...H.......1...  . .1..        .11H111H11111111MM
    H.  ....H...1HH11MH1.....      ....   ..1..       .11H11H111111H11111MM
    .  ....H..111111H1......                 1...      .H111H11H1H1H11111MM
      ....HHH..11111H1.......                .11..     HHHHHH1H11H11H1111MM
    .....2HHH....M11111.......    .          .HHH1.   HHHHHHHHH1HHHH1HHHHMM
    ...111HHHL  HMHH..........               1HHHHHM. MHHHHHHHHHH1H11H111MM
    ....11HHH....H1HH.........               .HHHHHM.1MHHHHHHHHH1H11H1111MM
    ..1111HHH. H11 1H.........1L1H..      ..H1MHHHHH. MHHHHHHHHHHHH1H1HH1MM
    11111HHHH1H1.H1.........L@L....   .LLL.HMHHHHH  KMHHHHHHHH1H1H1HH1HHHMM
    11111HHHH H..............HM6HH..  .*661HHHHHHHHMHMHHHHHHHHHHHH1H1HHHHMM
     11111HHHHH.   .H.......   ..    .        HHHHHHH...HHHHHHHHHHHHHHHHHMM
    111111HHHHH.   .........       .        HHHHHH1...1HHHHH1HHHHHH1H1H1HMM
    11111HHHHHHH.............     ....      1HHHHHH.....HHHHHHHHHHH1H1H1HMM
    111H1HHHHHHHHHHH........     ...H...   .HHHHH......1HHHHH1HHHHHHH1H11MM
    111H1HHHHHHHHHAH1.........   . ..      .HHHHH..........HHHHHHHHHHHHHHMM
    11H1HHHHHH......11........    L1LHHL. .HHHHH1.......* H1.HHHHHHHHHHHHMM
    11111H11..........11............L1  .HHHHHH..1.1.. .H1 ..HHHHHHHHHHHHMM
    1111111...........  ............    .HHHHH.. 1..  .H. .LHHHHHHHHHHHHHMM
    111111.........      .111.......   ..HHHHH1.1 .*   .  ..LHHHHHHHHHHHHMM
    11111..........         .1111..HHHHHHHHHH1..      8   ... HHHHHHHHHHHMM
    111..........            .1111HHHHHHHHH1111..       1.   111HHHHHHHHHMM
    1-...........            ...1HHHHHHHH11111..           111HHHHHHHHHHHMM
    111...............          ....1HHHHH11111@@..      . )1....11HHHHHHMM
    1......11..........          ...1HHH111*        .   ..@1......1HHHHHHMM
    1..............1B111.         .....H1              .........1HHHHHHHHMM
    ...............       ......   ....     .       ..1)11...........1HHHMM
    ...............    .1..  .    ..        .      .@111.............11HHMM
    .......1..111.  .111.      ..       .   .    HWZ@WWMMM H111..........MM
    .......11H1HH11111H1 ....11      ... ..  ....H11L1LL.................MM
    .......1111HHH1111.....111.   .   ......  1..HH11 11 ................MM
    .......111HHH1HH11111111H1. .1..   1.....  .H111.L..L..L.............MM
    .....11111HHHHHHHHH1111H111....... 11......1H11......................MM
    MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
    MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM
    M                                                                     M
    M              ZUR ERINNERUNG AN DEN BESUCH IM                        M
    M          HAUS ZUR GESCHICHTE DER IBM DATENVERARBEITUNG              M
    M              SINDELFINGEN IM NOVEMBER 2004                          M
    M                                                                     M
    MMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMMM

 


return to
main page